SDT References

This chapter contains a reference to the syntax used by ORCA¹ and SDT when referring to entities managed by ORCA and SDT.

Through these references, the ORCA and SDT environment provides, among other, a means to:

• Obtain a graphical trace back from Analyzer diagnostics to the source SDL diagrams
• Trace simulations in graphical mode
• Obtain a trace back from generated MSCs to the source SDL diagrams
• Navigate between SDL type diagrams, cross-reference diagrams, coverage charts and the source SDL diagrams
• Navigate between the generated PR or C files and the source SDL diagrams.

Table of Contents 

• General
• Syntax
• Examples

General

The concept "GR reference", introduced in the SDT 2.X tool family, has been extended in order to support references to virtually all entities that are managed in an ORCA and SDT 3.X environment (or will be managed in future versions):

• SDL diagrams
• SDL pages
• SDL symbols
• Text within an SDL symbol
• SDL Overview diagrams
• SDL-PR files
• OM, SC, MSC, HMSC diagrams
• OM, SC, HMSC pages
• OM, SC, MSC, HMSC symbols
• Text within an MSC symbol
• Text within an OM symbol²
• Cross-reference files
• Coverage files
• C files
• ASN.1 files
• Other ASCII text files

The term GR reference has been replaced by the term SDT reference. It is possible to retrieve SDT references from the ORCA and SDT tools using commands such as Show GR Reference in the SDL Editor, and to show the source that matches a reference using commands such as Go To Source in the Organizer.

Syntax

Below follows the syntax for an SDT reference:

<SDT_Reference> ::=
  `#SDTREF' `('
  ( <SDT_GR_Ref> | <SDT_Textfile_Ref>
  | <SDT_MSC_Ref> | <SDT_HMSC_Ref> | <SDT_OM_Ref>
  | <SDT_SC_Ref> )
  `)'

<SDT_GR_Ref> ::=
   `SDL' `,' <FileName> 
   [ `(' <PageName> `)' ]
   [ `,' <ObjectId> [ <Object_Coordinates> ]
   [ `,' <LineNumber> [ `,' <Column> ] ] ]

<SDT_Textfile_Ref> ::=
  `TEXT' `,' <FileName>
   [ `,' <LineNumber> [ `,' <Column> ] ]

<SDT_MSC_Ref> ::=
   `MSC' `,' <FileName>
   [ `,' <ObjectId> 
   [ `,' <LineNumber> [ `,' <Column> ] ] ]

<SDT_HMSC_Ref> ::=
   `HMSC' `,' <FileName>
   [ `(' <PageName> `)' ]
   [ `,' <ObjectId> [ <Object_Coordinates> ]
   [ `,' <LineNumber> [ `,' <Column> ] ] ]

<SDT_OM_Ref> ::=
   `OM' `,' <FileName>
   [ `(' <PageName> `)' ]
   [ `,' <ObjectId> [ <Object_Coordinates> ]
   [ `,' <LineNumber> [ `,' <Column> ] ] ]

<SDT_SC_Ref> ::=
   `SC' `,' <FileName> 
   [ `(' <PageName> `)' ]
   [ `,' <ObjectId> [ <Object_Coordinates> ]
   [ `,' <LineNumber> [ `,' <Column> ] ] ]

<FileName> ::=
  File name

<PageName> ::=
  name of a page according to SDT3.X rules

<ObjectId> ::=
  integer, unique id for object


<Object_Coordinates> =
  `(` <x-coord> `,' <y-coord> `)'

<x-coord> ::=
   x coordinates in mm from upper left corner
<y-coord> ::=
   y coordinates in mm from upper left corner

<LineNumber> ::=
   line number within symbol or file

<Column> ::=
   column within the line

Examples

Below follow some examples of SDT references.

Reference	Explanation
#SDTREF(SDL,test.sbk)	SDL diagram.
#SDTREF(SDL,test.sbk(P1))	SDL page
#SDTREF(SDL,test.sbk(P1),10)	SDL symbol
#SDTREF(SDL,test.sbk,10)	SDL symbol
#SDTREF(SDL,test.sbk(P1),10(30,130))	SDL symbol
#SDTREF(SDL,test.sbk(P1),10,5)	Line within symbol
#SDTREF(SDL,test.sbk(P1),10(30,130),5)	Line within symbol
#SDTREF(SDL,test.sbk(P1),10,5,15)	Column at line within symbol

Reference	Explanation
#SDTREF(MSC,test.msc)	MSC
#SDTREF(MCS,test.msc,10)	Symbol in MSC
#SDTREF(MCS,test.msc,10,5)	Line within symbol
#SDTREF(MCS,test.msc,10,5,15)	Column at line within symbol

Reference	Explanation
#SDTREF(OM,test.som)	OM diagram.
#SDTREF(OM,test.som(P1))	OM page
#SDTREF(OM,test.som(P1),10)	OM symbol
#SDTREF(OM,test.som,10(30,130))	OM symbol
#SDTREF(OM,test.som,10,5)	Line within symbol
#SDTREF(OM,test.som(P1),10(30,130),5)	Line within symbol
#SDTREF(OM,test.som(P1),10,5,15)	Column at line within symbol

Reference	Explanation
#SDTREF(TEXT,test.pr)	Text file
#SDTREF(TEXT,test.pr,10)	Line in text file
#SDTREF(TEXT,test.pr,10,15)	Column at line within file